
*  JieJie Microelectronics P-Spice Model Library
*  Filename	: JMSL0612AUQ_P v.20220620.txt
*  Product Name   : JMSL0612AUQ (PDFN3x3-8L)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 1.2
*  Release Date	: Jun20, 2022
*  Junction Temp (Tj): -40C ~ 175C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSL0612AUQ D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
Vmonitor D 18 0
RD 18 1 0.01
RS S 3 1E-009
RG G 17 2.5
CGS 3 G 7.1E-10
EGD 12 0 2 1 1

Etemp 17 2 VALUE = {(-3.0000000E-03*(TEMP-25))+((-3.4015100E-06)*(TEMP-25)^2)}
Gtemp 1 3 VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^2.8)}

VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 4E-10
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
Cbreak D 3 Cbreak  6.704100E-10
.MODEL Cbreak CAP (C = 1  VC1 = -2.961000E-02   VC2 = 2.633010E-04）

.model NMOS NMOS
+LEVEL = 3                     VMAX = 1E9                    ETA = 1E-4      
+VTO = 1.84                    TOX = 8E-10                   NSUB = 1E22    
+KP = 300                      U0 = 200                      KAPPA = 0.1    
+GAMMA = 0.151947              PHI = 0.5                     THETA = 0.2    
+DELTA = 200                   

.model DCGD D
+CJO = 2.1E-10                 VJ = 9                       M = 1.8  

.model DSUB D
+IS = 5E-12                    N = 1.06                      RS = 0.012   
+BV = 67.7                     xti = -6.5     

.model DLIM D
+IS = 1E-4   
.ends JMSL0612AUQ

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************

